home *** CD-ROM | disk | FTP | other *** search
/ Belgian Amiga Club - ADF Collection / BS1 part 60.zip / BS1 part 60 / Prof. Calc d1.adf / HDInstall < prev    next >
AmigaDOS Script File  |  1991-12-23  |  4KB  |  170 lines
  1. .KEY dest,help/s
  2. .BRA {
  3. .KET }
  4.  
  5. ; :ts=3
  6. ; HDInstall - Install Professional Calc onto a hard drive.
  7. ;
  8. ; Inputs:
  9. ;    dest   Directory to install ProCalc into
  10. ;    help   Print instructions
  11. ;
  12.  
  13. Assign PCalcInstOrig: ""
  14. Echo >ram:BlottoCD "CD PCalcInstOrig:"
  15.  
  16. ; Make sure he's running WB 1.3!
  17. ; Under 1.3, the "1 gt 2" test fails; we proceed to "FAILAT 10".
  18. ; Under 1.2, however, the IF command itself dies, since GT is not defined;
  19. ; execution is not suspended, and the ECHO and SKIP are seen.
  20. FAILAT 21
  21. IF >NIL: 1 gt 2
  22.         ECHO "*NVersion 1.3 of the Amiga Workbench software *E[;1mmust*E[m be"
  23.         ECHO "present before this installation can proceed.*N"
  24.         SKIP wrapup
  25. ENDIF
  26. FAILAT 10
  27.  
  28. ; Start with a fresh copy, to avoid any potential problems
  29. IF EXISTS RAM:PCalcInstall
  30.    DELETE RAM:PCalcInstall all quiet
  31. ELSE
  32.    MAKEDIR RAM:PCalcInstall
  33. ENDIF
  34.  
  35.  
  36. IF EXISTS C:COPY
  37.    C:COPY  C:Copy  RAM:PCalcInstall
  38. ENDIF
  39. CD ram:PCalcInstall    ; Search it without adding it to path
  40. IF EXISTS C:Assign
  41.    Copy C:Assign                   RAM:PCalcInstall
  42. ENDIF
  43. IF EXISTS C:Echo
  44.    Copy C:Echo                     RAM:PCalcInstall
  45. ENDIF
  46. IF EXISTS C:FailAt
  47.    Copy C:FailAt                   RAM:PCalcInstall
  48. ENDIF
  49. IF EXISTS C:If
  50.    Copy C:If                       RAM:PCalcInstall
  51. ENDIF
  52. IF EXISTS C:Else
  53.    Copy C:Else                     RAM:PCalcInstall
  54. ENDIF
  55. IF EXISTS C:Endif
  56.    Copy C:Endif                    RAM:PCalcInstall
  57. ENDIF
  58. IF EXISTS C:Makedir
  59.    Copy C:Makedir                  RAM:PCalcInstall
  60. ENDIF
  61. IF EXISTS C:Execute
  62.    Copy C:Execute                  RAM:PCalcInstall
  63. ENDIF
  64.  
  65. COPY ProCalc:misc RAM:PCalcInstall all quiet
  66.  
  67. Assign PCalcInst:       ; Make sure these start fresh, too.
  68.  
  69. ;
  70. ; Make sure needed system assignments exist.
  71. ;
  72. INSTUTIL isdir T:
  73. IF WARN
  74.    INSTUTIL isdir RAM:T
  75.    IF WARN
  76.       MAKEDIR ram:T
  77.    ENDIF
  78.    ASSIGN T: ram:T
  79. ENDIF
  80.  
  81. INSTUTIL isdir ENV:
  82. IF WARN
  83.    INSTUTIL isdir RAM:ENV
  84.    IF WARN
  85.       MAKEDIR ram:ENV
  86.    ENDIF
  87.    ASSIGN ENV: ram:ENV
  88. ENDIF
  89.  
  90.  
  91. ;
  92. ; HELP processing
  93. ;
  94. IF "{help}" eq "HELP"
  95.    SKIP showme
  96. ENDIF
  97.  
  98. INSTUTIL ask -dy "Do you need instructions [Y/N]? Y"
  99. IF WARN
  100.    SKIP noshow
  101. ENDIF
  102.  
  103. LAB showme
  104.    ProCalc:showme ProCalc:HELP-Install
  105. LAB noshow
  106.  
  107.  
  108. ;
  109. ; Make sure that the destination exists, that its name is
  110. ; in a useable form (ie. that it ends with a '/' if it's a directory),
  111. ; and that the user in fact wants to install into it.
  112. ;
  113. IF NOT EXISTS "{dest$SYS:}"
  114.    ECHO "*N ********** Couldn't find Hard Disk drawer {dest$SYS:} **********"
  115.    SKIP forhelp
  116. ENDIF
  117.  
  118. INSTUTIL isdir "{dest$SYS:}"
  119. IF WARN
  120.    CD RAM:PCalcInstall
  121.    ECHO "*N ********** {dest$SYS:} is not a drawer! **********"
  122. LAB forhelp
  123.    ECHO "*N For help, type"
  124.    ECHO "      EXECUTE ProCalc:HDInstall help"
  125.    ECHO "*N or double-click on the *"Help-Install*" icon in this drawer*N"
  126.    SKIP wrapup
  127. ENDIF
  128. CD RAM:PCalcInstall
  129.  
  130. ECHO "*N Answering *"No*" to the following question will cancel"
  131. ECHO " the installation.  Your hard drive will not be changed.*N"
  132. INSTUTIL ask -dy "Install Professional Calc onto {dest$SYS:} [Y/N]? Y"
  133. IF warn
  134.    ECHO " Installation aborted!*N"
  135.    SKIP wrapup
  136. ENDIF
  137.  
  138. ECHO >ram:PCalcInstall/DestPath1 "{dest$SYS:}"
  139. INSTUTIL <ram:PCalcInstall/DestPath1 >ram:PCalcInstall/DestPath2 fixdir
  140.  
  141. ASSIGN >nil: PCalcInstDest: "{dest$SYS:}"
  142.  
  143. ECHO "*N*N ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*N"
  144. ECHO " Begin installation of Professional Calc onto {dest$SYS:}*N"
  145.  
  146. INSTUTIL >ram:PCalcInstall/TempScript mergenl "==EXECUTE >nil: ram:PCalcInstall/Install-Proc """ ram:PCalcInstall/DestPath2 "=="""
  147. EXECUTE ram:PCalcInstall/TempScript
  148.  
  149. ECHO "*N --------------------------------------------------------------------"
  150. ECHO "*N*N Installation of Professional Calc complete."
  151. ECHO "*N ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*N"
  152.  
  153. ;
  154. ; Clean up after ourselves
  155. ;
  156. LAB wrapup
  157.  
  158. Execute RAM:blottoCD
  159. DELETE RAM:blottoCD quiet
  160.  
  161. Assign PCalcInst:
  162. Assign PCalcInstDest:
  163. Assign PCalcInstOrig:
  164.  
  165. RAM:PCalcInstall/InstUtil ask "Press RETURN."
  166. IF EXISTS RAM:PCalcInstall
  167.     DELETE >NIL: RAM:PCalcInstall all quiet
  168. ENDIF
  169.  
  170.